Never forget to email an attachment again

Outlook Attachment Reminder

We at the Inbox Alliance are always looking for ways to stop common email mistakes.  We have come across a great way to stop you forgetting to send an attachment with an email.  How often do you send an email, only to have to send another email apologising for not attaching the file you referred to?  It happens to us all the time.  Forgetting attachments is time wasting and irritating.

The below macro will check your emails for any words that contain 'attach', if it finds 'attach' without an attachment a reminder will pop-up and ask whether you want to send the email without the attachment.  While it isn't fool proof, it goes a long way to stopping this email mistake from occuring.

We found this solution at mark.bird.googlepages.com and the explanation of how to install it is taken from Mark Bird's website.

Adding a macro to Outlook is easy. Just copy everything below starting with "Private Sub" through "End Sub." In Outlook, select the "Tools | Macro | Visual Basic Editor" menu option. You may need to expand the project by clicking the plus signs under Project1 until you see ThisOutlookSession, and double-click it. Click into the big white empty page and hit Paste.

If you would likea screenshot of how the macro should look please go to Mark's website.

Click Save and you'll be all set. If you've previously disabled macros you'll need to enable them.

*Note: Outlook Express doesn't support macros.

*Update: Outlook counts files used in Signatures as attachments. If your signature uses one or more files, find the line intStandardAttachCount = 0 and make it equal the number of files in your signature. Thanks to Kevin Rowe for pointing this out.

 
Copy and Paste this:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
Dim m As Variant
Dim strBody As String
Dim intIn As Long
Dim intAttachCount As Integer, intStandardAttachCount As Integer

On Error GoTo handleError

'Edit the following line if you have a signature on your email that includes images or other files. Make intStandardAttachCount equal the number of files in your signature.
intStandardAttachCount = 0

strBody = LCase(Item.Body)

intIn = InStr(1, strBody, "original message")

If intIn = 0 Then intIn = Len(strBody)

intIn = InStr(1, Left(strBody, intIn), "attach")

intAttachCount = Item.Attachments.Count

If intIn > 0 And intAttachCount <= intStandardAttachCount Then
   
    m = MsgBox("It appears that you mean to send an attachment," & vbCrLf & "but there is no attachment to this message." & vbCrLf & vbCrLf & "Do you still want to send?", vbQuestion + vbYesNo + vbMsgBoxSetForeground)

    If m = vbNo Then Cancel = True
   
End If

handleError:

If Err.Number <> 0 Then
    MsgBox "Outlook Attachment Reminder Error: " & Err.Description, vbExclamation, "Outlook Attachment Reminder Error"
End If

End Sub

If you come across any other great email productivity saving tools, please tell us so we can share them.

For '8 email tips to save time and stop common mistakes' just complete our 10 minute Work Email Survey.

---